mirror of
https://github.com/espressif/esp-idf.git
synced 2024-10-05 20:47:46 -04:00
ec5eb1e5c2
Changes: KConfig: The option CONFIG_ESP32_RTCDATA_IN_FAST_MEM is added in Kconfig file for esp32 component. esp32.common.ld: added support of RTC_DATA_ATTR, RTC_RODATA_ATTR data placement into appropriate segment according to Kconfig option. esp32.ld: linker script is modified to set alias for memory segment selected by Kconfig option to place data. The segments for force placement are added for RTC_FAST_ATTR, RTC_SLOW_ATTR attributes. esp_attr.h: added new attributes RTC_FAST_ATTR, RTC_SLOW_ATTR for force placement into fest/slow memory. test_rtc_fast.c: Added unit test cases to check data placement into appropriate memory segment. Updated documentation for RTC_DATA_ATTR, RTC_FAST_ATTR, RTC_SLOW_ATTR in deep_sleep_stub.rst file. TW#18001 Closes https://github.com/espressif/esp-idf/issues/1553
89 lines
3.3 KiB
Plaintext
89 lines
3.3 KiB
Plaintext
/* ESP32 Linker Script Memory Layout
|
|
|
|
This file describes the memory layout (memory blocks) as virtual
|
|
memory addresses.
|
|
|
|
esp32.common.ld contains output sections to link compiler output
|
|
into these memory blocks.
|
|
|
|
***
|
|
|
|
This linker script is passed through the C preprocessor to include
|
|
configuration options.
|
|
|
|
Please use preprocessor features sparingly! Restrict
|
|
to simple macros with numeric values, and/or #if/#endif blocks.
|
|
*/
|
|
#include "sdkconfig.h"
|
|
|
|
/* If BT is not built at all */
|
|
#ifndef CONFIG_BT_RESERVE_DRAM
|
|
#define CONFIG_BT_RESERVE_DRAM 0
|
|
#endif
|
|
|
|
MEMORY
|
|
{
|
|
/* All these values assume the flash cache is on, and have the blocks this uses subtracted from the length
|
|
of the various regions. The 'data access port' dram/drom regions map to the same iram/irom regions but
|
|
are connected to the data port of the CPU and eg allow bytewise access. */
|
|
|
|
/* IRAM for PRO cpu. Not sure if happy with this, this is MMU area... */
|
|
iram0_0_seg (RX) : org = 0x40080000, len = 0x20000
|
|
|
|
/* Even though the segment name is iram, it is actually mapped to flash
|
|
*/
|
|
iram0_2_seg (RX) : org = 0x400D0018, len = 0x330000-0x18
|
|
|
|
/*
|
|
(0x18 offset above is a convenience for the app binary image generation. Flash cache has 64KB pages. The .bin file
|
|
which is flashed to the chip has a 0x18 byte file header. Setting this offset makes it simple to meet the flash
|
|
cache MMU's constraint that (paddr % 64KB == vaddr % 64KB).)
|
|
*/
|
|
|
|
|
|
/* Shared data RAM, excluding memory reserved for ROM bss/data/stack.
|
|
|
|
Enabling Bluetooth & Trace Memory features in menuconfig will decrease
|
|
the amount of RAM available.
|
|
|
|
Note: Length of this section *should* be 0x50000, and this extra DRAM is available
|
|
in heap at runtime. However due to static ROM memory usage at this 176KB mark, the
|
|
additional static memory temporarily cannot be used.
|
|
*/
|
|
dram0_0_seg (RW) : org = 0x3FFB0000 + CONFIG_BT_RESERVE_DRAM,
|
|
len = 0x2c200 - CONFIG_BT_RESERVE_DRAM
|
|
|
|
/* Flash mapped constant data */
|
|
drom0_0_seg (R) : org = 0x3F400018, len = 0x400000-0x18
|
|
|
|
/* (See iram0_2_seg for meaning of 0x18 offset in the above.) */
|
|
|
|
/* RTC fast memory (executable). Persists over deep sleep.
|
|
*/
|
|
rtc_iram_seg(RWX) : org = 0x400C0000, len = 0x2000
|
|
|
|
/* RTC fast memory (same block as above), viewed from data bus */
|
|
rtc_data_seg(RW) : org = 0x3ff80000, len = 0x2000
|
|
|
|
/* RTC slow memory (data accessible). Persists over deep sleep.
|
|
|
|
Start of RTC slow memory is reserved for ULP co-processor code + data, if enabled.
|
|
*/
|
|
rtc_slow_seg(RW) : org = 0x50000000 + CONFIG_ULP_COPROC_RESERVE_MEM,
|
|
len = 0x1000 - CONFIG_ULP_COPROC_RESERVE_MEM
|
|
}
|
|
|
|
/* Heap ends at top of dram0_0_seg */
|
|
_heap_end = 0x40000000 - CONFIG_TRACEMEM_RESERVE_DRAM;
|
|
|
|
_data_seg_org = ORIGIN(rtc_data_seg);
|
|
|
|
/* The lines below define location alias for .rtc.data section based on Kconfig option.
|
|
When the option is not defined then use slow memory segment
|
|
else the data will be placed in fast memory segment */
|
|
#ifndef CONFIG_ESP32_RTCDATA_IN_FAST_MEM
|
|
REGION_ALIAS("rtc_data_location", rtc_slow_seg );
|
|
#else
|
|
REGION_ALIAS("rtc_data_location", rtc_data_seg );
|
|
#endif
|